Pratique sur les boucles : Afficher les multiples d'un nombre

Énoncé 

Ecrire un algorithme qui affiche le nombre des entiers qui sont des multiples de 3 et inférieur à un nombre n donné par l'utilisateur.

Solution(s)

Plusieurs solutions peuvent être données. Il s'agit d'un autre exercice très classique pour commencer avec les boucles.

Premièrement, nous pouvons voir qu'il y a une borne supérieure à ne pas dépasser. Cela veut dire que le nombre d'itérations est connu et la boucle "Pour" peut être utilisée (toute boucle peut être écrite sous la forme Tant Que).

Ainsi, la solution la plus simple et la plus intuitive sera composée de :

• Une boucle qui parcours les valeurs jusqu'à n,
• Une structure conditionnelle pour vérifier est ce qu'il s'agit d'un multiple de 3 pour l'afficher.

En Pascal :

Program AfficherMultiples3;

Var 
 n, i : Integer;

Begin
 
 WriteLn('Faites entrer la limite n :');
 ReadLn(n);
 
 For i := 0 to n Do
  If (i mod 3 = 0) Then
  WriteLn(i, ' est un multiple de 3');
  
 ReadLn;
 
 
End.

En Java :

import java.util.Scanner;

public class AfficherMultiples3 {
 
 public static void main (String args[]) {
  
  System.out.println("(Java) Faites entrer la limite n :");
  
  Scanner entree = new Scanner(System.in);
  int n = entree.nextInt();
  
  for(int i = 0; i <= n; i++)
   if(i % 3 == 0)
    System.out.println(i + " est un multiple de 3");
  
 }
 
}

Le résultat d'exécution est exactement le même pour les deux codes :

D'habitude, l'étape suivante est de montrer que même avec ce petit code, on arrive à l'optimiser. En effet, pourquoi parcourir toutes les valeurs et faire le test pour chaque valeur. Il est possible de ne parcourir que les valeurs désirées, c'est à dire, il est possible de parcourir les multiples de 3 seulement. L'idée réside dans le pas effectué par la boucle Pour à chaque itération.

En Pascal (j'utilise fpc qui ne supporte pas des pas dans la boucles For, alors je suis obligé de passer à la boucle While):

Program AfficherMultiples3;

Var 
 n, i : Integer;

Begin
 
 WriteLn('Faites entrer la limite n :');
 ReadLn(n);
 
 i := 0;
 While(i <= n)Do
 Begin
  WriteLn(i, ' est un multiple de 3');
  i := i + 3; { Le compteur change par 3 à chaque fois }
 End;
  
 ReadLn;
 
 
End.

En Java :

import java.util.Scanner;

public class AfficherMultiples3 {
 
 public static void main (String args[]) {
  
  System.out.println("(Java) Faites entrer la limite n :");
  
  Scanner entree = new Scanner(System.in);
  int n = entree.nextInt();
  
  for(int i = 0; i <= n; i+=3 /* le pas est 3 */)
   System.out.println(i + " est un multiple de 3");
  
 }
 
}

Ces deux codes donnent exactement les mêmes résultats mais dans un temps d'exécution plus court.

Les fonctions : par analogie avec les fonctions mathématiques

Les fonctions sont présentes dans tous les programmes. Il est pratiquement impossible d'écrire un programme qui effectue plusieurs tâches sans faire recours aux fonctions (pas impossible mais très difficile, pénible et coûteux).

Dans cet article, je vais essayer de présenter la notion de fonction en la rapprochant de la notion de fonction mathématique; une notion largement plus maîtrisée.

Une fonction mathématique à une seule variable peut être déclarée par la forme suivant :

Cette déclaration se divise en deux partie :

• La première partie désigne l'ensemble de départ; l'ensemble dans lequel la variable d'entrée va prendre ses valeurs.
• La deuxième partie désigne l'ensemble d'arrivé; l'ensemble dans lequel la fonction prend ses valeurs.

Un exemple concret :

Ainsi, cette fonction prend une variable réelle et renvoie une valeur réelle. Cette valeur est calculée comme étant le double du cub de la valeur prise en entrée.

Plus généralement, une fonction à n variables est déclarées de la manière suivante :

La première partie désigne un produit cartésien de plusieurs ensemble, c'est à dire, la fonction prend un t-uple en entrée et prend ses valeur dans un ensemble d'arrivé.

Un exemple concret :

Cette fonction prend un couple de nombres réels et prend ses valeurs dans l'ensemble des nombres réels. La deuxième partie montre la formule de calcule.

La deuxième partie peut être un peu plus compliqué qu'une formule unique. La fonction "valeur absolue", par exemple, est définie comme suit :

Ainsi, la formule varie selon la valeur de la variable.

Passons maintenant à la programmation.

La déclaration d'une fonction doit préserver, au moins, les notions requises par la déclaration mathématique. Autrement, la conception d'une fonction sera vraiment difficile à imaginer.

Ainsi, il faut garder :

• Les ensemble de départ et l'ensemble d'arrivé.
• La formule du calcul.

En Pascal, la déclaration sera ainsi :

function f([parametres : ensembles de depart]) : [ensemble d'arrivée];

reprenons l'exemple d'une fonction à une seule variable :

function f(x : Real) : Real;

La deuxième partie est facilement réalisable grace aux structures de contrôle offertes par le langage (le conditionnel et les boucles). Ainsi le code de la première fonction sera :

Function f(x : Real) : Real;
Begin
 f := 2 * x * x * x;
End;

Et la fonction qui implémente la fonction "valeur absolue" sera :

Function valeurAbsolue(n : Integer) : Integer;
Begin
 If(n >= 0)Then
  valeurAbsolue := n
 Else
  valeurAbsolue := -1 * n;
End;

Pour appeler une fonction, c'est comme appeler une personne :), c'est par son nom sans oublier de lui fournir les valeurs nécessaires en entrée (les paramètres). Un exemple complet :

Program ExempleFonctions;

Function f1(x : Real) : Real;
Begin
 f1 := 2 * x * x * x;
End;

Function f2(x, y : Real) : Real;
Begin
 f2 := x * x + y * y;
End;

Function valeurAbsolue(n : Integer) : Integer;
Begin
 If(n >= 0)Then
  valeurAbsolue := n
 Else
  valeurAbsolue := -1 * n;
End;

Begin
 
 WriteLn(f1(3.14):4:2);
 WriteLn(f2(2.5, 3.5):4:2);
 WriteLn(valeurAbsolue(-10));
 
End.

Les tableaux : Quoi et Pourquoi ?

Définition

Les tableaux sont des structures de données statiques.

Une structure de données est une manière d'organiser les données pour les traiter plus facilement (Wikipedia).

Statique désigne la taille fixe : un tableau est d'une taille (nombre de cellules) fixe.

Un tableau (array en anglais) est une structure de données qui consiste en un ensemble d'éléments ordonnés accessibles par leur indice (ou index) (Wikipedia).

Pourquoi utiliser un tableau ?

Un tableau est utilisé lorsque les données à manipuler satisfont les trois conditions suivantes :

1. Nous voulons sauvegarder toutes les données,
2. Nous avons des données de même types,
3. Nous allons appliquer le même traitement sur toutes les données.

Exemple 1 : Utilisation des tableaux recommandée

Supposons que nous voulons saisir les notes de tous les étudiants d'un groupe pour ensuite calculer la moyenne et connaître le min et le max.

Dans ce cas, les trois conditions sons satisfaites :

1. Nous voulons nous rappeler de toutes les notes,
2. Les notes sont toutes de même nature et de même types,
3. Le calcul de la moyenne et la recherche du min et de max nécessitent des traitement identiques sur chaque notes (addition et comparaison)

Exemple 2 : Utilisation des tableaux non recommandées

Supposons que nous avons les données suivantes : la taille (en m) d'une personne, son poids (en kg), son rythme cardiaque, sa tension et sa température au moment de la consultation médicale.

Ces données sont toutes des nombres (entiers ou réels). Nous voulons les sauvegarder dans le dossier médical du patient. Néanmoins, ces données ne peuvent pas subir des traitements identiques : la somme de la taille et du poids, la comparaison entre le poids et tension ou la multiplication de la tempértaure et du rythme cardiaque sont toutes des opérations qui n'ont aucun sens.

Ainsi, l'utilisation des tableaux n'est pas recommandée dans ce cas.

Déclaration et code : solution du premier exemple :

Program PremierExempleTableau;

Const
 N = 10;
 
Var 
 notes : Array [1..N] of Real; {toutes les données sont de même type, 
          la taille est fixe}
 i : Integer; {L'indice pour pouvoir accéder aux différentes valeurs}
 
 somme, max, min : Real;

Begin
 
 For i:= 1 to N Do
 Begin
  WriteLn('Donnez la ', i, 'ème valeur :');
  ReadLn(notes[i]);
 End;
 
 somme := notes[1];
 min := notes[1];
 max := notes[1];
 
 For i:= 2 to N Do
 Begin
  somme := somme + notes[i];
  
  If (notes[i] < min) Then
   min := notes[i];
   
  If (notes[i] > max) Then
   max := notes[i];
 End;
 
 WriteLn('Les notes saisies sont : ');
 For i:= 1 to N Do
 Begin
  Writeln('notes[', i, '] = ', notes[i]:2:2);
 End;
 
 WriteLn('La somme de ces notes est ', somme:2:2);
 WriteLn('La moyenne de ces notes est ', (somme / N):2:2);
 WriteLn('La plus grande note est ', max:2:2);
 WriteLn('La plus petite note est ', min:2:2);
 
End.

Un peu de pratique avec les boucles : calcul du cosinus

Enoncé
Ecrire le programme qui calcule la valeur du sinus grâce au développement limité suivant :

(source)
Solution
Dans cet exemple, j'ai présenté un problème très simiaire. On suit le même mode de raisonnement et on utilise l'écriture sous forme de série comme suit :

Le code Pascal sera ainsi :

Program CalculCosinus;

Var
 i, n, signe, factoriel : Integer;
 x, cosinus, puissancex : Real;

Begin
 
 WriteLn('Donnez le x pour cacluler cos(x) :');
 ReadLn(x);
 WriteLn('Donnez n qui désigne ma précision du calcul :');
 ReadLn(n);
 
 signe := 1;
 factoriel := 1;
 puissancex := 1;
 cosinus := 0;
 
 For i:= 1 to n Do
 Begin
  cosinus := cosinus + (signe * puissancex) / factoriel;
  WriteLn(signe, ' ', puissancex, ' ', factoriel, ' ', cosinus);
  signe := signe * -1;
  puissancex := puissancex * x * x;
  factoriel := factoriel * (2 * i - 1) * (2 * i);
  
 End;
 
 WriteLn('Valeur calculée par cet algorithme : ', cosinus:1:2);
 WriteLn('Valeur calculée par l''API de pascal : ', cos(x):1:2);
 
End.

Dans ce code comme le précédent, l'effet de bord est présent.

Un peu de pratique avec les boucles : calcul du sinus

Enoncé
Ecrire le programme qui calcule le sinus en utilisant le développement limité suivant :

(source)
Solution
Un autre exercice classique pour pratiquer avec les boucles.

L'astuce est simple : il ne faut pas penser à chaque élément d'une manière indépendant; il faut le baser sur l'élément précédent. En d'autres termes, pensez à utiliser l'écriture série de cette formule :

Ainsi, l'objectif est de calculer les éléments (les termes) de la sommes l'un après l'autre en se basant sur l'élément précédent.

Le code en Pascal sera :

Program CalculSinus;

Var
 i, n, signe, factoriel : Integer;
 x, sinus, puissancex : Real;

Begin
 
 WriteLn('Donnez le x pour cacluler sin(x) :');
 ReadLn(x);
 WriteLn('Donnez n qui désigne la précision du calcul :');
 ReadLn(n);
 
 signe := 1;
 factoriel := 1;
 puissancex := x;
 sinus := 0;
 
 For i:= 1 to n Do
 Begin
  sinus := sinus + (signe * puissancex) / factoriel;
  signe := signe * -1;
  puissancex := puissancex * x * x;
  factoriel := factoriel * (2 * i) * (2 * i + 1);
 End;
 WriteLn('Valeur calculée par cet algorithme : ', sinus:1:2);
 WriteLn('Valeur calculée par l''API de pascal : ', sin(x):1:2);
 
End.

Pour les deux exemples, j'ai donné 4 comme précision. Cela m'évite un effet de bord à cause de valeur 11! (11 * 10 * 9 * 8 * 7 * 6 * 5 * 4 * 3 * 2 * 1) si je donne 5 comme précision. Evidemment, toute valeur supérieure à 5 provoquera le même problème.

Afficher tous les nombres premiers inférieurs à un nombre donné

Enoncé
Ecrire un programme qui lit un entier n et affiche tous les nombres premiers inférieurs à n.

Solution
Dans cet exercice, l'enseignant tente de compliquer les choses pour pousser les étudiants à utiliser une boucle à l'intérieur d'une autre. C'est un autre exercice classique que nous rencontrons dans la majorité des livres d'introduction à l'algorithmique.

Le programme qui vérifie si un nombre donné est premier est expliqué ici.

Tous ce qui reste à faire c'est de parcourir les valeurs inférieurs à "n" et de tester pour chaque nombre est ce qu'il est premier ou pas.

Le code sera ainsi :

Program Premiers;

Var 
 n, i, j : Integer;
 diviseur : Boolean;

Begin
 
 WriteLn('Donnez la limite n : ');
 ReadLn(n);
 
 WriteLn('Les nombres premiers inférieurs à ', n, ' sont : ');
 {Boucle extérieure pour le parcours des valeurs}
 i := 2;
 While (i <= n) Do
 Begin
 
  j := 2;
  diviseur := false;
  
  {Boucle intérieur pour voir est ce que 
   la valeur i est un nombre premier}
  While ((j < i) And not(diviseur)) Do
  Begin
   If (i mod j = 0) Then
    diviseur := true
   Else
    j := j + 1;
  End;
  
  If (not(diviseur)) Then
   WriteLn(i);
  
  {Vérification de la valeur suivante}
  i := i + 1;
 End;
 
End.

Vérifier si un nombre est premier

Enoncé
Ecrire un programme qui lit un entier "n" et vérifie s'il est entier.

Solution
Comme j'ai mentionné ici, l'astuce du diviseur est un excellent moins pour faire des travaux dirigés sur la notion de la variable booléenne. Cette dernière est utilisée très souvent dans les boucles de type "Tant que" et "Répéter jusqu'à" comme une condition d'arrêt (pour sortir de la boucle).

Ainsi, les auteurs et les enseignants tentent de mettre cette "petite" astuce de diviseur dans des boucles.

Dans le cas de cet exercice, l'idée est de vérifier s'il est premier ou pas, c'est à dire, de rechercher un autre diviseur de "n" que "1" et "n" lui même. Cela implique un parcours des valeurs de 2 à n - 1 (l'optimisation n'est pas vraiment ma priorité actuellement) et voir si on peut trouver un diviseur.

On sort de la boucle si :

1. On termine le parcours des valeurs de 2 à n - 1 sans trouver un diviseur et le nombre n est déclaré premier.
2. On trouve un diviseur alors on n'a plus besoin de vérifier autre chose et le nombre n est déclaré non premier.

La présence de deux conditions dans la définition de la boucle nous oblige à faire une vérification pour savoir "pourquoi avons nous quitter la boucle ?".

Ainsi, le code sera de la forme :

Program Premier;

Var
 n, i : Integer;
 diviseur : Boolean;

Begin

 WriteLn('Donnez un nombre à tester : ');
 ReadLn(n);
 
 i := 2;
 diviseur :=  false;
 
 While (not(diviseur) And (i < n)) Do
 Begin
  If (n mod i = 0) Then
   diviseur := true
  Else
   i := i + 1;
 End;
 
 {Vérification pourquoi a-t-on quitté la boucle}
 If (diviseur) Then
  WriteLn('n n''est pas un nombre premier')
 Else
  WriteLn('n est un nombre premier');
 
End.

L'opérateur "modulo" : un point essentiel pour comprendre la différence entre une définition théorique (mathématique) et une définition pratique (appliquée, informatique)

Enoncé
Ecrire un programme qui lit deux entiers a et b et vérifie est ce que b est un diviseur de a.

Solution
Ma principale motivation pour cette article est une solution que je lis plusieurs fois durant les séances de TD Algorithmique pour les étudiants MI. Les étudiants en Mathématiques et Informatique sont généralement des matheux qui maîtrise les maths et qui projèctent chaque nouvelle notion acquise sur une notion mathématiques.

Dans le cas de vérification si un nombre divise un autre, le code que je lis souvent est le suivant :

Program Diviseur;

Var
 a, b, k : Integer;

Begin
 ReadLn(a, b);
 If (k * b = a) Then
  WriteLn('b divise a')
 Else
  WriteLn('b ne divise pas a');
 
End.

Cette solution n'est même pas "compilable". En effet, la variable k n'a jamais été initialisée. Cela donne des avertissements (Warning) sous des compilateur et des erreur (Error) sous d'autres.

Mais cette solution n'est pas vraiement loin de la réalité. En effet, les étudiants, qui gardent encore un esprit matheux par excellence, reposent sur la définition suivante :

Soit a et b deux entiers.
On dit que b est un diviseur de a s'il existe un entier k tel que k.b = a.

L'erreur n'est pas dans la définition mais dans la traduction de la définition. L'erreur faite par les étudiants ici est plus simple de ce qu'elle parraît. En effet, ils ont montré deux confusions :

1. La déclaration algorithmique est différente de la déclaration mathématique. Décalrer une variable en algorithmique ne veut pas dire qu'elle prendra une valeur sur le champs.
2. L'ordinateur va chercher la bonne valeur pour eux.

Ainsi, une traduction plus correcte de la définition sera de la forme :

Program VerifierDiviseur;

Var
 a, b, k : Integer;
 diviseur : Boolean;

Begin
 ReadLn(a, b);
 k := 2;
 diviseur := false;
 
 While (not(diviseur) And (k < a)) Do
 Begin
  If (k * b = a) Then
   diviseur := true
  Else
   k := k + 1;
 End;
 
 If (diviseur) Then
  WriteLn('b divise a')
 Else
  WriteLn('b ne divise pas a');
 
End.

La suposition "il existe un entier k" nous oblige à le chercher, c'est à dire à parcourir les valeurs des nombres entiers, d'où la boucle.

Alors ce qu'il faut faire, c'est  de choisir la bonne définition. C'est aussi simple que cela. La définition à prendre est la définition la plus élémentaires que nous enseignons aux enfants :

Soient a et b deux entiers.
On dit que b est un diviseur de a si le reste de division de a sur b est nul.

Comment choisir la bonne définition ? Il n'y a pas une méthode exacte; c'est par la pratique, la lecture des codes et l'expérience. Dans ce cas, il fallait lister des opérations possibles et penser à choisir la définition la plus proche d'une telle ou telle opération ou bien celle qui nécessite un code minimal.

Le code sera ainsi :

Program VerifierDiviseur;

Var
 a, b : Integer;

Begin
 ReadLn(a, b);
 
 If (a mod b = 0) Then
  WriteLn('b divise a')
 Else
  WriteLn('b ne divise pas a');
 
End.

Dans les exemples suivants, vous allez voir que cette vérification n'est pas réalisée juste pour faire un affichage. Elle est utilisée pour aider les étudiants à comprendre et utiliser la notion d'une variable booléenne.

Triangle d'étoiles

Ennoncé
Ecrire un programme qui lit un entier "n" et affiche par la suite un triangle d'étoiles de hauteur "n". Par exemple, si n = 5, l'affichage sera :
*
**
***
****
*****

Solution
Cet exercice est un autre exercice classique pour aider les apprenants avec les boucles. Le principe pratiqué dans ce cas est le principe des boucles imbriquées (ici). Deux petites différences :

1. La borne supérieure de la boucle est lue à partir du clavier.
2. On affiche des "*" au lieu des indices utilisés dans les boucles.

Code en Pascal :

Program TriangleEtoiles;
 
Var 
 n, i, j : Integer;

Begin
 
 WriteLn('Donnez la hauteur de triangle : ');
 ReadLn(n);
 
 For i := 1 to n do
 Begin
  For j := 1 to i do
   Write('*');
  WriteLn;
 End; 
 
End.

Boucles imbriquées : boucle à l'intérieur d'une autre boucle

Pour ce petit code, je n'ai pas d'énnoncé. Je vais présenter, brièvement, la notion des boucles imbriquées.

Une boucle nous permet de faire un passage sur un ensemble de valeurs (intervalle, valeurs dans un tableau, etc.). Ce passage peut être vu comme le parcours d'une ligne; d'une seule dimension.

Les boucles imbriquées nous permettent de faire un peu plus de cela. Elles nous permettent d'effectuer un parcours dans deux dimensions : pour chaque valeur de la première boucle (boucle extérieure), nous faisons un parcours (passage) entier dans la deuxième boucle (boucle intérieure).

Un code exemple (en Pascal) :

Program ExempleBI;

Const 
 n = 10;
 
Var 
 i, j : Integer;

Begin
 
 For i := 1 to n do
 Begin
  For j := 1 to n do
   Write(j, ' ');
  WriteLn;
 End; 
 
End.

Le résultat d'exécution est :

Le parcours peut ne pas être complet : il se peut que les limites des deux boucles ne soient pas basées sur les mêmes variables :

Program ExempleBI2;

Const 
 n = 9;
 m = 15;
Var 
 i, j : Integer;

Begin
 
 For i := 1 to n do
 Begin
  Write(i, ' : ');
  For j := 1 to m do
   Write(j, ' ');
  WriteLn;
 End; 
 
End.

Il se peut même que la deuxième boucle fait appel à l'indice de la première boucle. Cela veut dire que les passages effectués par la deuxième boucle ne sont pas de même taille, néanmoins, cela ne change pas la structure du programme et cela reste un parcours en deux dimensions. Exemple :

Program ExempleBI3;

Const 
 n = 10;
 
Var 
 i, j : Integer;

Begin
 
 For i := 1 to n do
 Begin
  For j := 1 to i do
   Write(j, ' ');
  WriteLn;
 End; 
 
End.

La somme des chiffres d'un nombre entier

Exercice 
Ecrire un programme qui calcule la somme des chiffres d'un entier lu à partir du clavier

Solution 
En revenant au code pérsenté ici, la modification à apporter est minimale. En effe, dans code, nous avons affiché les chiffres du nombres, c'est à dire, nous nous sommes limités à les utiliser avec la méthode "Afficher" seulement.

Pour calculer la somme, il suffit d'utiliser ces chiffres dans une somme et non pas dans l'affichage. Ainsi, les modifications à apporter sont :

1. Ajouter une variable qui va contenir la somme,
2. Initialiser cette variabe à 0 ('élément neutre de l'opération d'addition),
3. Ajouter chaque chiffre extraît à la somme au lieu de l'afficher,
4. Améliorer l'affichage (enlever quelques "Afficher" et ajouter une autre).

Le code résultat sera, en Pascal :

Program SommeChiffres;

Var 
 n, c, s : Integer;

Begin
 s := 0;
 
 WriteLn('Donnez un nombre entier');
 ReadLn(n);
 
 While (n > 0) Do
 Begin
     c := n mod 10;
  s := s + c;
  n := n div 10;
 End;
 WriteLn('La somme des chiffres est : ', s);
End.

En Java :

import java.util.Scanner;

public class SommeChiffres {
 
 public static void main (String args[]) {
  
  Scanner s = new Scanner(System.in);
  int somme = 0;
  
  System.out.println("Donnez un nombre entier :");
  int n = s.nextInt();
  
  while(n > 0){
   somme += n % 10;
   n = n / 10;
  }
  System.out.println("La somme des chiffres est : " + somme);
  
  
 }
}

L'exécution est identique pour les deux codes :

Extraire les chiffres d'un nombre entier

Exercice
Ecrire un programme qui affiche les chiffres d'un nombre lu à partir du clavier.

Soution
Cet exercice est l'un des exercices classiques. Il vise à donner un exemple de manipulation sur deux éléments :

1. Boucles "Tant que" (while)
2. Extraîre les chiffres d'un nombre.

L'extraction d'un chiffre (une position) dans un nombre n'est pas aussi simple que l'extraction d'une lettre à partir d'une chaîne de caractères; il ne faut pas confondre les deux situations.

Dans le cas d'une chaîne de caractères, nous avons un tableau de caractères. En mémoire, chaque caractère occupe une case (d'un ou de deux octets, selon le langage et la plate-forme). Ainsi, il suffit de connaître la position d'un caractère pour l'extraire. Le parcours peut être réalisé avec une boucle "Pour" (connaissant la taille de la chaîne de caractères).

Dans le cas d'un nombre, nous avons une seule valeur sauvegarder dans un seul emplacement mémoire (de un, deux, quatre ou huit octets). La valeur est sauvegardée en binaire et les chiffres ne sont pas distingués. Ainsi, connaître la position d'un chiffre de facilite pas son extraction. En effet, il faut faire appel à des calculs pour extraire ce chiffre. Dans ce cas les deux opérations nécessaires sont la division et le modulo.Pour récupérer un chiffre, il faut faire deux choses :

1. Couper le nombre pour rendre le chiffre recherché dans la position des unités. Cela est fait par la division sur une puissance de 10.
2. Extraire le chiffre qui devient (après avoir coupé le nombre) le modulo 10.

Par exemple, si le nombre n = 123456. Pour extraire le troisième chiffre à partir de droite, il faut :

1. Diviser le nombre sur 100 (10^(position - 1)), n devient 1234.
2. Extraire le nombre la module 10, le chiffre extrait sera 4.

Le parcours est beaucoup plus simple parce que on fait des divisions successives sur 10; aucun besoin pour utiliser la fonction puissance de 10.

Il nous reste à signaler deux remarques très importantes :

1. Contrairement à un tableau (ou chaîne de caractères), le parcours se fait de droite à gauche.
2. L'opération détruit la valeur d'origine. Si vous aurez besoin d'utiliser cette valeur plus loin dans le programme alors il faut la sauvegarder dans une variable.

En Pascal :

Program ExtraireChiffres;

Var 
 n, c : Integer;

Begin
 WriteLn('Donnez un nombre entier');
 ReadLn(n);
 
 WriteLn('Ses chiffre (de droite à gauche) sont :');
 While (n > 0) Do
 Begin
     c := n mod 10;
     WriteLn(c);
     n := n div 10;
 End;
End.

En Java :

import java.util.Scanner;

public class ExtraireChiffres {
 
 public static void main (String args[]) {
  
  Scanner s = new Scanner(System.in);
  
  System.out.println("Donnez un nombre entier :");
  int n = s.nextInt();
  
  System.out.println("Ses chiffres sont :");
  while(n > 0){
   System.out.println(n % 10);
   n = n / 10;
  }
  
 }
}

L'exécution est identique pour les deux codes :